AutoCAD 3DMAX C语言 Pro/E UG JAVA编程 PHP编程 Maya动画 Matlab应用 Android
Photoshop Word Excel flash VB编程 VC编程 Coreldraw SolidWorks A Designer Unity3D
 首页 > VFP

超级素数问题二——判断一个数是否为超级素数

51自学网 http://www.51zixue.net

原文及讨论:http://hi.bccn.net/space-67595-do-blog-id-1810.html

***  判断一个数是否为超级素数 By Tiger5392 (C)Copyright 2006-2006
***
***  相关知识
***      超级素数:一个素数,去掉个位是素数;去掉个位和十位也是素数;......;
***  直到保留到最高位依然是素数,这个素数称为超级素数。
***
***  编程思路
***      1.素数一定不能是1。给定的数若为超级素数,则高位不能是1。
***      2.素数一定不能被2整除(2除外)。给定的数若为超级素数,则各位数字不能含有0,2,4,6,8(高位2除外)。
***      3.素数一定不能被5整除(5除外)。给定的数若为超级素数,则各位数字不能含有0,5(高位5除外)。
***      4.经过分析,有这样的结论:
***        (1)高位可能为2,3,5,7,而绝对不能是0,1,4,6,8,9;
***        (2)除高位外的其它各位数字可能是1,3,7,9,而绝对不能是0,2,4,5,6,8。
***
PARAMETERS nNum
PRIVATE nNum,nNum1,cNum,nCnt,lIsSupperPrime
IF TYPE("nNum")#CHR(78) OR INT(nNum)#nNum OR nNum<1 &&参数为大于0的整数
  RETURN .F.
ENDIF
lIsSupperPrime=INLIST(VAL(SUBSTR(ALLTRIM(STR(nNum)),1,1)),2,3,5,7) &&提取高位数字并判断是否为素数
IF lIsSupperPrime=.F.
  RETURN .F.
ENDIF
FOR nCnt=0 TO LEN(ALLTRIM(STR(nNum)))-1
  nNum1=INT(nNum/10^nCnt)              &&将原数去掉从个位开始的nCnt位
  cNum=SUBSTR(ALLTRIM(STR(nNum1)),2)   &&提取除高位外的其余部分
  IF "0"$cNum OR "2"$cNum OR "4"$cNum OR "5"$cNum OR "6"$cNum OR "8"$cNum
    lIsSupperPrime=.F.
    EXIT
  ELSE
    lIsSupperPrime=.T.
  ENDIF
  IF !IsPrime(nNum1)
    lIsSupperPrime=.F.
    EXIT
  ENDIF
ENDFOR
RETURN lIsSupperPrime
*** EOF(): IsSupperPrime By Tiger5392 (C)Copyright 2006-2006

FUNCTION IsPrime
PARAMETERS nNumber
PRIVATE nNumber,lOk,nCnt
IF nNumber<10  &&10以内的数直接判断是否为素数
  lOk=INLIST(nNumber,2,3,5,7)
ELSE
  IF MOD(nNumber,2)=0 OR MOD(nNumber,3)=0 OR MOD(nNumber,5)=0 OR MOD(nNumber,7)=0
    lOk=.F.
  ELSE
    lOk=.T.
    FOR nCnt=2 TO SQRT(nNumber)
      IF MOD(nNumber,nCnt)=0
        lOk=.F.
        EXIT
      ENDIF
    ENDFOR
  ENDIF
ENDIF
RETURN lOk
*** EOF(): IsPrime By Tiger5392 (C)Copyright 2006-2006

 

 

 
上一篇:超级素数问题四——统计X以内的超级素数的个数  下一篇:求两个正整数的最大公约束和最小公倍数