以下为利用ASSEMBLY,BASIC,PASCAL,C,FORTRAN 等程式语言，将一个24x 24之点阵字形，放大成为48x 48，并分别比较其处理速度、占用空间以及制作时间。
    为了正确计算执行时间，特意作 10,000 次处理，至于指定的24x 24字形，则假设为一空格。

一、ASSEMBLY

    组合语言变化无穷，先以一般的作法，用点阵位移来处理。
    1: PAGE   60, 132
    2: CG     SEGMENT
    3: BUFIN  DB    72 DUP(0)
    4: BUFOT  DB  72*4 DUP(0)
    5:          ASSUME CS:CG,DS:CG,ES:CG
    6: START:
    7:          MOV     AX,CG
    8:          MOV     DS,AX
    9:          MOV     ES,AX
   10:          CLD
   11:          MOV     BP,10000        ; 处理10,000次
   12: S3:
   13:          SUB     CX,CX
   14:          MOV     BX,CX
   15:          MOV     DX,1803H           ; 计数用
   16:          MOV     SI,OFFSET BUFIN  ; 24*24 点阵起始位址
   17:          MOV     DI,OFFSET BUFOT  ; 预定48*48储存位址
   18: MVBYTE:
   19:          MOV     BH,DL           ; 做三列
   20: MVDB:
   21:          LODSB               ; 取原点阵
   22:          MOV     BL,AL
   23:          MOV     CL,8           ; 做八位元
   24: MVDB1:
   25:          RCL     BL,1           ; 左移一次
   26:          PUSHF               ; 保存状态
   27:          RCL     AX,1           ; 两字同时左移一次
   28:          POPF               ; 取出原移位状态
   29:          RCL     AX,1           ; 再一次，得双位点值
   30:          LOOP    MVDB1           ; 八次回路
   31:          STOSW               ; 存入
   32:          MOV     [DI+4],AX        ; 上下放大一行
   33:          DEC     BH           ; 共 3列
   34:          JNZ     MVDB
   35:          ADD     DI,6           ; 移向次行
   36:          DEC     DH
   37:          JNZ     MVBYTE           ; 共24行
   38:          DEC     BP           ; 执行10,000次
   39:          JNZ     S3           ; 完成
   40:          MOV     AX,4C00H
   41:          INT     21H
   42: CG     ENDS
   43:          END     START
    本程式制作时间，为十五分钟。
    经汇编后，得934 字元的执行程式，执行耗时14.5秒。
    若将上段程式加以分析，可以发现到此段程式执行时间全部浪费在23至30这一段「回路」中。为了增加速度，可以将空间加大，避开回路，连续执行八次「移位」动作如次：
   23:          RCL     BL,1
   24:          RCL     AX,1
   25:          SHL     AX,1
   26:          同上共八次
   …
   47:          MOV     CX,AX           ; AX中为单位元值
   48:          SHR     CX,1           ; CX得到双位元点阵值
   49:          OR      AX,CX           ; 双位元点阵合并
    似此，程式增大了36字元，但执行时间却减少为 7.1秒，速度快了一倍！
    是不是还是更好的方法呢？相信一定多得不计其数。比如说，我们已知原点阵放大一倍后点形为「双点」，以双点做表，取其对应之值，即可免除各点移位的手续，再将原程式第18条以下改为：
   18: VT2:
   19:          CALL    MVBYTE           ; 放大一行
   20:          SUB     SI,3           ; 纵向尚须放大一次
   21:          CALL    MVBYTE           ; 再放大一行
   22:          DEC     DH           ; 完成否？
   23:          JNZ     VT2           ; 再做
   24:          RET               ; 完成
   25: MVBYTE:
   26:          MOV     CL,DL           ; 一行有三字元
   27: MVDB:
   28:          LODSB               ; 取一字元
   29:          MOV     AH,AL           ; 分置两处
   30:          AND     AX,0FF0H           ; AH,AL 各取四位元
   31:          SHR     AL,1           ; 右移四次还原
   32:          SHR     AL,1
   33:          SHR     AL,1
   34:          SHR     AL,1
   35:          MOV     BL,AL
   36:          MOV     AL,BYTETB[BX]    ; 左字元取预设表值
   37:          MOV     BL,AH
   38:          MOV     AH,BYTETB[BX]    ; 右字元取表值
   39:          STOSW               ; 得二字元置缓冲器中
   40:          LOOP    MVDB           ; 做三次
   41:          RET
   42                       ; 转换表
   43: BYTETB DB    000H,003H,00CH,00FH,030H,033H,03CH,03FH
   44:          DB    0C0H,0C3H,0CCH,0CFH,0F0H,0F3H,0FCH,0FFH
   45: CG     ENDS
   46:          END     START

    再换个方法，因为有个XALT的指令，是专为这种程式所设计的。由第25条起，调整如下：
   25: MVBYTE:
   26:          MOV     CL,4           ; 供AL左移四位用
   27:          MOV     BX,OFFSET BYTETB
   28: MVDB:
   29:          LODSB               ; 取一字元
   30:          MOV     AH,AL           ; 分置两处
   31:          AND     AX,0F00FH        ; AH,AL 各取四位元
   32:          SHR     AL,CL
   33:          XLAT                 ; 将[BX+AL]值放AL中
   34:          XCHG    AL,AH
   35:          XLAT
   36:          STOSW
   37:          DEC     DL
   38:          JNZ     MVDB
    如此，执行程式959 字元，执行速度3.2 秒，效率更佳。

 1/2    1 2 下一页 尾页