带星号的密码输入
title ***简单密码输入进阶 by lluct***

data segment   ;定义数据段
headmsg db      ' ',0dh,0ah
 db '+----------------------------------------------+',0dh,0ah
 db '| Simple input password system for asm program |',0dh,0ah
 db '|                have a fun.^-^.               |',0dh,0ah
 db '| Poor Programmer:lluct     Date:march,21 2004 |',0dh,0ah
 db '+----------------------------------------------+',0dh,0ah
        db      0dh,0ah,'PLEASE INPUT PASSWORD:','$'
;定义头信息组
msg1 db 'PASSWORD RIGHT!','$'
;定义输入密码正确后显示出来的信息
msg2 db 'PASSWORD ERROR!','$'
;定义输入密码错误后显示出来的信息
cmpare db '5201314','$'
;定义密码
input db 100 dup (?)
;定义输入的字符串,字符串必须用db定义,长度为100个字节
data ends   ;数据段结尾

code segment   ;定义代码段
 assume cs:code  ;规定cs的内容
 assume ds:data  ;规定ds的内容

start_program:   ;程序从这里开始
 mov ax,data  ;把data段地址赋给ax
 mov ds,ax  ;ds置初值,data的段地址
 mov si,0  ;变址寄存器初值为0

 call enter  ;调用显示回车换行子程序
        lea     dx,headmsg ;输出头信息组的偏移地址
 call dispchs  ;调用显示字符串子程序

repeat_input:   ;循环输入单个字符
 mov ah,08h  ;调用8号功能:键盘输入字符(无回显)
 int 21h  ;完成输入
        mov     dl,2ah  ;输出ascii码的*号
        push    ax  ;保护原来输入的字符
        call dispch  ;调用单个字符回显子程序
        pop     ax  ;恢复原来输入的字符
        cmp al,0dh  ;是否回车
 je finished_input ;是就转移到finished_input
 mov input[si],al ;保存单个字符
 inc si  ;访问下一个相对地址
 jmp repeat_input ;无条件转移到repeat_input

finished_input:   ;完成输出
 mov input[si],24h ;给刚才输入的字符串加结束标志($)
 call enter

 mov si,0  ;si置0
 mov di,0  ;di置0
 mov cx,8  ;设置检测密码的长度,要包括结束标志
check_password:   ;检测密码
 cmp cx,0  ;cx为是否为0
 je right  ;是就转移到right
 mov bl,input[si] ;把input的si的地址内的信息传送到bl
 mov dl,cmpare[di] ;把cmpare的di的地址内的信息传送到dl
 cmp dl,bl  ;检查dl和bl是否一样
 jne error  ;不是就转移到error
 inc si  ;si加1
 inc di  ;di加1
 dec cx  ;cx减1
 jmp check_password 

right:
 call  enter
 lea dx,msg1
 call dispchs
 call enter
 jmp exit

error:
 call enter
 lea dx,msg2
 call dispchs
 mov dl,07h  ;输出ascii码的报警(响铃)控制符bel(07h)
        call    dispch
 call enter
 jmp exit

exit:   mov     ah,4ch  ;4c号功能调用:终止当前程序并返回
 int 21h  ;返回dos

enter proc near  ;显示回车换行子程序
 mov dl,0dh  ;输出ascii码的回车控制符cr
 call dispch
 mov dl,0ah  ;输出ascii码的换行控制符lf
 call dispch
 ret   ;返回
enter endp

dispch proc near  ;显示单个字符子程序
        mov     ah,02h  ;2号功能调用:显示器输出字符
 int 21h  ;完成输出显示
        ret
dispch endp

dispchs proc near  ;显示字符串子程序
 mov ah,09h  ;9号功能调用:显示字符串
 int 21h
 ret
dispchs endp

code ends   ;代码段结尾
        end     start_program ;结束汇编

;把以上代码复制到记事本等文本程序中,并保存.(如passwd2.asm)
;编译:masm passwd2.asm
;连接:link passwd2.obj
;执行:passwd2.exe

 2/2   首页 上一页 1 2